SELECTED_CHAR_KIND (The GNU Fortran Compiler)

### 8.249 `SELECTED_CHAR_KIND` — Choose character kind ¶

Synopsis:

  `RESULT = SELECTED_CHAR_KIND(NAME)`

Description:

  `SELECTED_CHAR_KIND(NAME)` returns the kind value for the character set named NAME, if a character set with such a name is supported, or -1 otherwise. Currently, supported character sets include “ASCII” and “DEFAULT”, which are equivalent, and “ISO_10646” (Universal Character Set, UCS-4) which is commonly known as Unicode.

Class:

  Transformational function

Arguments:

  NAME | Shall be a scalar and of the default character type.

Example:

      program character_kind
        use iso_fortran_env
        implicit none
        integer, parameter :: ascii = selected_char_kind ("ascii")
        integer, parameter :: ucs4  = selected_char_kind ('ISO_10646')

        character(kind=ascii, len=26) :: alphabet
        character(kind=ucs4,  len=30) :: hello_world

        alphabet = ascii_"abcdefghijklmnopqrstuvwxyz"
        hello_world = ucs4_'Hello World and Ni Hao -- ' &
                      // char (int (z'4F60'), ucs4)     &
                      // char (int (z'597D'), ucs4)

        write (*,*) alphabet

        open (output_unit, encoding='UTF-8')
        write (*,*) trim (hello_world)
      end program character_kind

Standard:

  Fortran 2003 and later